前言

　　Android 項目日常開發(fā)過程中，經常需要打包給到非開發(fā)人員驗收或調試，例如測試階段，就要經常基于測試服務器地址，打包安裝包，給到組內測試人員進行測試，并且 BUG 修復完成之后也需要再次打包給到測試人員回測。
　　為了減免機械性的重復步驟，為項目配置不同的 渠道（Product Flavors），不同渠道對應不同的服務器地址，并且為每一個渠道創(chuàng)建一個 Gradle Task 執(zhí)行打包并上傳至蒲公英的操作，同時在蒲公英中配置 Webhook ，最終可實現：執(zhí)行對應 渠道（Product Flavors）的 Gradle Task，即可自動打包并上傳至蒲公英，并將包更新信息同步至企業(yè)微信、釘釘、飛書等工作群組，使得包更新流程可視化，并簡化了開發(fā)和測試聯(lián)調流程。

實現步驟

1.創(chuàng)建 pgyer-upload.gradle 文件

　　每個渠道的 Task 執(zhí)行內容一致：打包并記錄更新信息后上傳至蒲公英 ，所以抽取公共內容（方法）創(chuàng)建如下 pgyer-upload.gradle 文件

import groovy.json.JsonSlurper

import java.net.http.HttpClient
import java.net.http.HttpRequest
import java.net.http.HttpResponse
import java.nio.charset.StandardCharsets
import java.nio.file.Files
import java.text.SimpleDateFormat

ext.uploadApk = this.&uploadApk

/**
 * Sept 1 創(chuàng)建執(zhí)行任務
 */

/**
 * 蒲公英 ApiKey
 * https://www.pgyer.com/account/api
 * TODO 替換成自己的蒲公英 APIkey
 */
static String getApiKey() {
    return "myApiKey"
}

/**
 * 上傳 apk 到蒲公英
 * @apk 安裝包文件
 * @flavorName 渠道名
 */
def uploadApk(File apk, String flavorName) {
    if (apk == null) {
        throw new RuntimeException("apk file not exists!")
    }
    def apkName = apk.name
    println "*************** Upload Init ***************"
    //渠道信息
    String buildFlavorName = flavorName
    if (flavorName == "DemoRelease") {
        buildFlavorName = "Test"
    } else if (flavorName == "DevRelease") {
        buildFlavorName = "Dev"
    } else if (flavorName == "ProduceRelease") {
        buildFlavorName = "Produce"
    } else if (flavorName == "BetaRelease") {
        buildFlavorName = "Beta"
    }
    println "flavorName = ${buildFlavorName}  apkName = ${apkName}  apkSize = ${apk.size()}"
    // Git 提交信息
    String commitLogStr = getGitCommitLogByCount(5)
//    String commitLogStr = getGitCommitLogByToDay()
    def appModule = project.rootProject.project(':app')
    def appVersionName = appModule.android.defaultConfig.versionName
    def appVersionCode = appModule.android.defaultConfig.versionCode
    //更新信息
    String updateDescription = "\n[${getBranchName()}]：${buildFlavorName}-${appVersionName}-${appVersionCode}" +
            "\n${commitLogStr}"
    println "updateDescription : ${updateDescription}"

    println "*************** Upload Get Token ***************"
    //組裝cosToken需要的的參數，見https://www.pgyer.com/doc/view/api#fastUploadApp
    List<KeyValue> cosTokenParams = new ArrayList<>()
    //API KEY
    cosTokenParams.add(new KeyValue("_api_key", apiKey))
    //屬于android平臺
    cosTokenParams.add(new KeyValue("buildType", "android"))
    //更新描述
    cosTokenParams.add(new KeyValue("buildUpdateDescription", updateDescription))
    // 獲取上傳的 token ,見 https://www.pgyer.com/doc/view/api#fastUploadApp
    HttpResponse<String> response = postFormData("https://www.pgyer.com/apiv2/app/getCOSToken", cosTokenParams)
    def resp = new JsonSlurper().parseText(response.body())
    println ">>>> Get Token Response :\n${response.body()}"

    println "*************** Uploading Apk File ***************"
    // 上傳文件到第上一步獲取的 URL，參數從上一步獲取，這里需要解析參數
    String paramsString = String.valueOf(resp.data.params)
    String[] params = paramsString.substring(1, paramsString.length() - 1).split(',')
    List<KeyValue> list = new ArrayList<>()
    if (params != null) {
        for (i in 0..<params.length) {
            String rawParam = params[i].trim()
            String parsedKey = rawParam.substring(0, rawParam.indexOf("="))
            String parsedValue = rawParam.substring(rawParam.indexOf("=") + 1, rawParam.length())
            //添加參數
            list.add(new KeyValue(parsedKey, parsedValue))
        }
    }
    // 添加apk文件
    list.add(new KeyValue("file", apk.getPath(), true))
    HttpResponse<String> uploadResponse = postFormData(resp.data.endpoint, list)
    if (uploadResponse.statusCode() == 204) {
        println(">>>> Upload Success ")
    } else {
        println(">>>> Upload Fail :" + uploadResponse.body())
    }
    println "*************** Upload Completed ***************"
}

static HttpResponse<String> postFormData(String url, List<KeyValue> list) {
    long requestStartTime = System.nanoTime()
    String boundary = "*********"
    // Result request body
    List<byte[]> byteArrays = new ArrayList<>()
    // Separator with boundary
    byte[] separator = ("--" + boundary + "\r\nContent-Disposition: form-data; name=").getBytes(StandardCharsets.UTF_8)
    // Iterating over data parts
    for (i in 0..<list.size()) {
        // Opening boundary
        byteArrays.add(separator)
        def entry = list[i]
        // If value is type of Path (file) append content type with file name and file binaries, otherwise simply append key=value
        if (entry.isFile) {
            java.nio.file.Path path = new File(entry.getValue()).toPath()
            String mimeType = Files.probeContentType(path)
            byteArrays.add(("\"" + entry.getKey() + "\"; filename=\"" + path.getFileName()
                    + "\"\r\nContent-Type: " + mimeType + "\r\n\r\n").getBytes(StandardCharsets.UTF_8))
            byteArrays.add(Files.readAllBytes(path))
            byteArrays.add("\r\n".getBytes(StandardCharsets.UTF_8))
        } else {
            byteArrays.add(("\"" + entry.getKey() + "\"\r\n\r\n" + entry.getValue() + "\r\n")
                    .getBytes(StandardCharsets.UTF_8))
        }
    }
    byteArrays.add(("--" + boundary + "--").getBytes(StandardCharsets.UTF_8))
    def publisher = HttpRequest.BodyPublishers.ofByteArrays(byteArrays)
    HttpRequest httpRequest = HttpRequest
            .newBuilder(URI.create(url))
            .version(HttpClient.Version.HTTP_1_1)
            .header("Content-Type", "multipart/form-data;boundary=" + boundary)
            .POST(publisher)
            .build()
    return HttpClient.newHttpClient().send(httpRequest, HttpResponse.BodyHandlers.ofString())
}

/**
 * 獲取當天提交日志
 * @return
 */
static String getGitCommitLogByToDay() {
    //獲取 git 提交日志
    Calendar calendar = Calendar.getInstance()
    String endTime = new SimpleDateFormat("yyyy-MM-dd").format(calendar.getTime())
    calendar.add(Calendar.DATE, -1)
    String startTime = new SimpleDateFormat("yyyy-MM-dd").format(calendar.getTime())
    //git 命令
    String gitCommand = "git log --pretty=\"%s\" --since=\"${startTime}\" --before=\"${endTime}\""
    //println "getUpdateDescription() --> gitCommand = ${gitCommand}"
    String description = gitCommand.execute().text.trim()
    return description
}

/**
 * 獲取最近 n 條提交日志
 */
static String getGitCommitLogByCount(int count) {
    //git 命令
    String gitCommand = "git log -${count} --pretty=format:\"%s\""
    //println "getUpdateDescription() --> gitCommand = ${gitCommand}"
    String description = gitCommand.execute().text.trim()
    return description
}

/**
 * 獲取分支名
 */
static String getBranchName() {
    String gitCommand = "git rev-parse --abbrev-ref HEAD"
    return gitCommand.execute().text.trim()
}

class KeyValue {
    String key
    String value
    boolean isFile

    KeyValue(String key, String value) {
        this(key, value, false)
    }

    KeyValue(String key, String value, boolean isFile) {
        this.key = key
        this.value = value
        this.isFile = isFile
    }

    @Override
    String toString() {
        return "{key:" + key + ", value:" + value + ", isFile:$isFile}"
    }
}

　　該代碼主要執(zhí)行 APK 上傳至蒲公英的操作，并上傳指定更新內容：

• [ Git 分支名]:渠道名-APP版本名-APP版本號
• 5 條 Git Commit 信息

2.引用自定義 Gradle 文件

　　在項目的 build.gradle 文件最外層執(zhí)行

apply from: "pgyer-upload.gradle"

3.配置渠道（非必須）

　　在 app module 的 build.gradle 文件 android 層內執(zhí)行

    /**
     * Sept 3 配置渠道 (非必須)
     */
    flavorDimensions "channel"
    productFlavors {
        // 生產環(huán)境
        produce {
            buildConfigField "String", "HOST", "\"${HOST}\""
        }
        // 預生產環(huán)境
        beta {
            buildConfigField "String", "HOST", "\"${HOST_BETA}\""
        }
        // 開發(fā)環(huán)境
        dev {
            buildConfigField "String", "HOST", "\"${HOST_DEV}\""
        }
        // 測試
        demo {
            buildConfigField "String", "HOST", "\"${HOST_TEST}\""
        }
        productFlavors.all {
                // 遍歷 productFlavors 多渠道，設置渠道號
            flavor -> flavor.manifestPlaceholders.put("CHANNEL", name)
        }
    }

　　此處代碼中的 produce、beta 、dev、demo 均為自定義的渠道名，可根據自身業(yè)務需求進行增刪修改，其中 HOST 為自定義的變量名，不同渠道引用值不一樣（示例中的值來源配置在項目的 gradle.properties 文件中，如下所示），項目編譯后，在代碼中即可通過 BuildConfig.FLAVOR 和 BuildConfig.HOST 獲取當前編譯環(huán)境的 渠道名 和 自定義變量 HOST 的值

# gradle.properties 文件內
# Host
HOST=https://hao123.com
HOST_BETA=https://hao123.com:1008
HOST_TEST=https://hao123.com:1010
HOST_DEV=https://hao123.com:1024

　　Android Studio 中，可通過左下方 Build Variants 手動切換編譯渠道

切換編譯渠道

4.創(chuàng)建打包 Task

　　同樣在 app module 的 build.gradle 文件 android 層內執(zhí)行

    /**
     * Sept 4 創(chuàng)建打包 Task
     * 遍歷所有可執(zhí)行的 variants 創(chuàng)建對應的打包 Task
     * 生成后的路徑及名稱：Tasks/build/pushApk[productFlavorsName][Release/Debug]
     * eg:Tasks/build/pushApkDevRelease
     */
    android.applicationVariants.all { variant ->
        String taskSuffix = variant.name.capitalize()
        if (taskSuffix.contains("Release") || taskSuffix.contains("Debug")) {
            task("pushApk${taskSuffix}") {
                dependsOn ":app:assemble${taskSuffix}"
                group 'build'
                description 'Custom task for gradle'
                doLast {
                    variant.outputs.all { output ->
                        // 執(zhí)行腳本任務
                        uploadApk(output.outputFile, taskSuffix)
                    }
                }
            }
        }
    }

5.執(zhí)行 Gradle Task

　　按上述步驟操作之后，先執(zhí)行 Sync Project with Gradle Files 生成不同渠道對應的打包 Task
　　然后可通過以下兩種方式進行執(zhí)行打包并上傳的腳本任務

• 直接執(zhí)行 Task : Tasks/build/pushApkDevRelease
  

  直接執(zhí)行 Task 步驟 1
  
  
  直接執(zhí)行 Task 步驟 2

• 通過 Gradle 命令執(zhí)行 Task : gradle pgyerUploadDevRelease
  

  通過 Gradle 命令執(zhí)行 Task

5.1執(zhí)行效果

Gradle Task 執(zhí)行完畢

企業(yè)微信群更新信息示例

6.補充說明

6.1 關于變種（variants）

　　在 Android 應用程序構建過程中，變種（variants）是指基于不同構建配置或渠道進行構建的應用程序版本。
　　Android Gradle 插件使用變種來生成不同版本的應用程序，以滿足不同的需求，如不同的構建類型、不同的渠道或不同的產品變體等。
　　每個變種具有自己的構建配置和特定的屬性設置，例如包名、應用圖標、應用名稱等。通過創(chuàng)建不同的變種，可以實現以下目標：

1.構建類型（Build Types）：構建類型定義了不同的構建環(huán)境和配置，例如調試版（Debug）和發(fā)布版（Release）。每個構建類型可以具有自己的代碼、資源、簽名證書、編譯標志等。
2.渠道（Product Flavors）：渠道是為了滿足不同目標市場或用戶群體的需求而定義的版本變體。通過渠道，可以為不同的渠道定制應用程序的內容，如應用程序圖標、名稱、啟動畫面、配置文件等。
3.變體（Build Variants）：變體是構建類型和渠道的組合，表示一個具體的應用程序版本。每個變體都有其自己的構建輸出，如 APK 文件或可安裝的應用程序包。

　　通過定義和配置不同的變種，開發(fā)人員可以輕松地構建適用于不同需求的不同版本的應用程序，以便進行測試、發(fā)布和分發(fā)。

6.2 上傳 APK 文件失敗

上傳文件至蒲公英失敗

1.降低項目 JDK 版本為 11 或以下即可解決該問題（大部分情況下需要同步修改項目的 Gradle 和 Gradle Plugin 版本，改動較大，不建議）
2.改用自定義 Gradle 插件形式創(chuàng)建 Task ，即可在 Task 中引用第三方的網絡請求庫如 OKHttp ，使用第三方的網絡請求庫封裝 form-data，解決該問題（無需改動項目 JDK、Gradle 及 Gradle Plugin 版本，推薦使用該方案）

　　方案 2 的具體實施，將在下一篇文章中進行演示
　　PS:如果你們可以在自定義 Gradle 文件中引用到第三方的網絡請求庫或者是正確編寫攜帶文件的 form-data 網絡請求，則可以自行更改部分代碼后修復該問題

6.3 Gradle 控制臺中文顯示異常

　　在 studio64.exe.vmoptions 文件中輸入

# 解決 gradle 控制臺中文亂碼問題
-Dfile.encoding=utf-8

打開 studio64.exe.vmoptions 文件

編輯 studio64.exe.vmoptions 文件

6.4 Android Studio 右側 Gradle 欄內無法看到 Tasks 列表

　　在 Android studio 的 Setting 中找到最底部 Experimental ，取消如下圖中的勾選并應用

顯示 Gradle Tasks 列表

6.5 蒲公英 Webhook 配置

　　參考 https://seed.pgyer.com/WGNQkEpP