? ? ? ? 我們緊接著上一部分的內(nèi)容，繼續(xù)討論表達(dá)式。
? ? ? ? 有了上一部分的基礎(chǔ)，相信大家對這樣的抽象描述已經(jīng)有所了解了。類似的，我們可以直接寫出包含關(guān)系和邏輯運(yùn)算符的表達(dá)式的描述。
relation_expression : additive_expression
| relation_expression < additive_expression
| relation_expression <= additive_expression
| relation_expression > additive_expression
| relation_expression >= additive_expression
equality_expression : relation_expression
| equality_expression == relation_expression
| equality_expression != relation_expression
logical_and_expression : equality_expression
| logical_and_expression && equality_expression
logical_or_expression : logical_and_expression
| logical_or_expression || logical_and_expression
? ? ? ? 不知道大家有沒有注意到一個細(xì)節(jié)：這些表達(dá)式為何這樣安排？這其實涉及到C語言中運(yùn)算符優(yōu)先級的問題，例如：&&就比||優(yōu)先級高。也就是說，在列出的這些表達(dá)式描述中，運(yùn)算符優(yōu)先級從上到下依次遞減。其實，在上一部分我們處理四則運(yùn)算表達(dá)式時也是基于同樣的考慮：乘除法優(yōu)先級高于加減法。只是這里列出的由表達(dá)式順序決定運(yùn)算符優(yōu)先級的方式更加明顯而已。
? ? ? ? 在寫出帶賦值運(yùn)算符的表達(dá)式之前，我們需要理解一下C語言中的兩個概念：左結(jié)合和右結(jié)合。
- 左結(jié)合
對于表達(dá)式a + b + c，C語言是默認(rèn)執(zhí)行(a + b) + c這樣的運(yùn)算順序（除非用括號顯示地進(jìn)行操作分配）。這樣的運(yùn)算方式就稱之為左結(jié)合。 - 右結(jié)合
對于表達(dá)式a = b = c + d，C語言是默認(rèn)執(zhí)行a = (b = (c + d))這樣的運(yùn)算順序（除非用括號顯示地進(jìn)行操作分配）。這樣的運(yùn)算方式就稱之為右結(jié)合。
? ? ? ? 再回過頭看之前我們寫出來的這些表達(dá)式的描述方法，它們都出現(xiàn)在自己運(yùn)算符的左邊，這樣保證了我們能夠按照左結(jié)合的方式去處理。那么，觸類旁通，包含賦值運(yùn)算符的表達(dá)式的描述就該寫成：
expression : logical_or_expression
| logical_or_expression = expression
我不知道商業(yè)化的編譯器是怎樣實現(xiàn)的這個過程，但是通過學(xué)習(xí)這部分的內(nèi)容，對于C語言表達(dá)式的運(yùn)算實際結(jié)果就有了一個清晰的認(rèn)識，知其然也知其所以然了。
我們將表達(dá)式的這些描述方法都匯總起來，之前用primary_expression表示的，現(xiàn)在可以都用expression來描述，這樣就擴(kuò)展了C語言所支持的表達(dá)式形式的范圍。例如，primary_expression可以更新為：
primary_expression : ( expression )
| CHAR
| INT
| ID
? ? ? ? 到此，我們的表達(dá)式描述已經(jīng)基本上涵蓋了C語言中出現(xiàn)的大部分表達(dá)式，剩下沒有出現(xiàn)的我們將在后面進(jìn)行介紹。
? ? ? ? 至于實現(xiàn)，都大同小異，這里就不在重復(fù)了。
3.2 語句（statement）
? ? ? ? 在前面的表達(dá)式中，我們從最小單元primary_expression起逐漸構(gòu)建起最終完整的表達(dá)式expression。但是，和表達(dá)式的這種自底向上的分析方法相反，我們需要采用自頂向下的方式來分析C語言中出現(xiàn)的語句，因為語句都是層層嵌套的，并不按照遞歸的方式進(jìn)行實現(xiàn)。因此，為了方便，我們將語句分成以下幾類：
-
表達(dá)式語句（expression statement）
表達(dá)式后面用分號結(jié)尾的語句，語法結(jié)構(gòu)為：
expression_statement : expression ;
-
跳轉(zhuǎn)語句（jump statement）
類似于break，continue和return的這類語句，目的是使程序“跳轉(zhuǎn)”到期望的位置上，它們的語法結(jié)構(gòu)可以表示為：
jump_statement : RETURN ;
| RETURN expression ;
| BREAK ;
| CONTINUE ;
-
迭代語句（iteration statment）
即進(jìn)行循環(huán)運(yùn)算的過程的語句，比如for和while，它們的語法結(jié)構(gòu)可以表示為：
iteration_statement : FOR ( expression ; expression ; expression ) statement
| WHILE ( expression ) statement
| DO statement WHILE ( expression ) ;
這里的statement就是所有語句的集合。
-
選擇語句（selection statement)
即有選擇性地執(zhí)行的語句，如if和switch。它們的語法結(jié)構(gòu)如下：
selection_statement : IF ( expression ) statement
| IF ( expression ) statement ELSE statement
-
復(fù)合語句（compound statement）
就是一對大括號內(nèi)的所有語句（可能不太準(zhǔn)確，因為大括號內(nèi)還可以包含聲明，我們將在后面詳細(xì)介紹），它的語法結(jié)構(gòu)可以表示為：
compound_statement : { declaration_list }
| { declaration_list statement_list }
這里的statement_list和declaration_list是語句和聲明的組合，可以描述為：
statement_list : statement
| statement_list statement
declaration_list : declaration
| declaration_list declaration
-
空語句（empty statement）
只包含分號的語句，語法結(jié)構(gòu)為：
empty_statement : ;
? ? ? ? 最后，我們將這些語句組合在一起，得到最終的語句集合描述：
statement : expression_statement
| jump_statement
| iteration_statement
| selection_statement
| compound_statement
| empty_statement
? ? ? ? 一旦搭建了底層的實現(xiàn)模板，不管是表達(dá)式還是語句，只需要按照這樣的一種模式，就能非常簡單快速地編寫語法分析的實現(xiàn)代碼了，具體代碼我們會在后面介紹。
? ? ? ? 語法分析的過程就是這樣，給定期望的語法模板，如果匹配，就進(jìn)行下一項匹配；否則，停止并返回錯誤。下一部分即將分析的聲明部分也是這樣，大家可以看一看C語言代碼，如何歸納總結(jié)出它們的描述。
實現(xiàn)簡易的C語言編譯器（part 0）
實現(xiàn)簡易的C語言編譯器（part 1）
實現(xiàn)簡易的C語言編譯器（part 2）
實現(xiàn)簡易的C語言編譯器（part 3）
實現(xiàn)簡易的C語言編譯器（part 5）
實現(xiàn)簡易的C語言編譯器（part 6）
實現(xiàn)簡易的C語言編譯器（part 7）
實現(xiàn)簡易的C語言編譯器（part 8）
實現(xiàn)簡易的C語言編譯器（part 9）
實現(xiàn)簡易的C語言編譯器（part 10）
實現(xiàn)簡易的C語言編譯器（part 11）
