1. 前向渲染是最常用的一種渲染路徑，每次Draw的時候都要對一個物體都要進行進行一次（或者多次）光照計算，然后再對下一個物體進行光照計算。如果在Fragment shader中計算，這種計算量是很大的。
2. 前向渲染在pass中要使用“LightMode”=“ForwardBase”等標簽。使用這個標簽后unity才能給內置的一些變量正確賦值。如_WorldSpaceLightPos0，_LightColor0等。在ForwardBase的Pass中會計算最重要的平行光、逐頂點/SH光源與LightMaps和環境光。
3. 前向渲染路徑還有一種路徑為"ForwardAdd"路徑，包含此標簽的Pass會計算額外的逐像素光源，每個Pass對應一個光源。也就是說如果場景中有m個光源，那么就會執行對應的Pass m次，如果shader中沒有給對應的光源編寫Pass，則物體不會受這個光源的影響。
4. 一個前向渲染實例：包含一個最重要的平行光，4個點光源。其中環境光，平行光在ForwardBase 的Pass中逐像素計算（frag中）（還可以計算光照貼圖等）。4個點光源（V5.6中設置為auto不好使，設置為Important）在ForwardAdd中逐像素計算，每個點光源執行一次ForwardAdd Pass。考慮了光源衰減因子，平行光不衰減，點光源采用unity中內置變量計算衰減，使用衰減紋理計算，避免了過多的距離平方開方計算等。

Shader "FFD/ForwardRenderingBasePass"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            Tags{"LightMode" = "ForwardBase"}
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fwdbase //可以正確得到光源衰減等信息

            #include "UnityCG.cginc"
            #include "Lighting.cginc"
            #include "AutoLight.cginc"

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 pos : SV_POSITION;
                float3 worldNormal : NORMAL;
                SHADOW_COORDS(2)
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            
            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                o.worldNormal = mul(v.normal,(float3x3)unity_WorldToObject);
                TRANSFER_SHADOW(o);
                return o;
            }
            
            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);

                float3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                float3 worldNormal = normalize(i.worldNormal);

                fixed4 ambient = fixed4(UNITY_LIGHTMODEL_AMBIENT.xyz,1);
                fixed4 diffuse = fixed4(_LightColor0.xyz*saturate(dot(worldNormal,worldLightDir)),1);
                col = col*(ambient+diffuse);
                fixed shadow = SHADOW_ATTENUATION(i);
                col = shadow*col;
                return col;
            }
            ENDCG
        }


        Pass{
            Tags { "LightMode" = "ForwardAdd"}
            Blend One One
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fwdadd   //可以正確得到光源衰減等信息

            #include "unitycg.cginc"
            #include "lighting.cginc"
            #include "autolight.cginc "

            struct v2f{
                float4 pos : SV_POSITION;
                float3 normalWorld : NORMAL;
                float4 posWorld : TEXCOORD0;
            };

            v2f vert(appdata_base IN)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(IN.vertex);
                o.normalWorld = mul(IN.normal,(float3x3)unity_WorldToObject);
                o.posWorld = mul(IN.vertex,unity_ObjectToWorld);
                return o;
            }
            fixed4 frag (v2f IN) : SV_Target
            {
                fixed atten;
                #ifdef USING_DIRECTIONAL_LIGHT
                    fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                    atten = 1;
                #else
                    fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz - IN.posWorld.xyz);
                    float3 lightCoord = mul(unity_WorldToLight,IN.posWorld).xyz;
                    atten = tex2D(_LightTexture0,dot(lightCoord,lightCoord).rr).UNITY_ATTEN_CHANNEL;

                #endif
                fixed3 diffuse = _LightColor0.xyz * atten * saturate(dot(worldLightDir,normalize(IN.normalWorld)));
                return fixed4(diffuse,1);
            }
            ENDCG
        }
    }
    FallBack "Specular"
}